99 IFA=0THENA=1:LOAD"BLINKOBJ",8,1
100 REM POKE56,28:POKE55,0:CLR FOR VIC, POKE56,60:POKE55,0:CLR FOR +4/16
110 V1=785:V2=786:CO=646:HI=192:REM FOR +4/16, V1=1281:V2=1282:CO=1339:HI=60
120 REM FOR VIC V1=1:V2=2:CO=646:HI=28
130 POKEV1,0:POKEV2,HI
140 REM ** USR() IS AT $C000, $3C00 ON THE +4/16, $1C00 FOR VIC **
150 SD=16384: REM ** SET DELAY FLAG
160 DB=8192 : REM ** DISABLE BLINK
170 EB=4096 : REM ** ENABLE BLINK
180 SB=2048 : REM ** STOP COLOR FROM BLINKING
190 MB=1024 : REM ** MAKE COLOR START BLINKING
200 VB=512  : REM ** RETURN VALUE OF BLINKING COLOR
210 RC=256  : REM ** RESET ALL COLORS-NO BLINKING
220 REM *** NOW WE DEMONSTRATE BLINK
230 RD$="[221][144]**** RED ****[221]":GR$="[221][144]*** GREEN ***[221]":PRINT"[147]"
240 POKE 53281,0:POKE 53280,0:REM MAKE BACKGROUND BLACK
250 REM COLOR 0,1,7:COLOR 4,1,7 FOR +4/16 IN LINE 240
260 REM POKE36879,8 FOR VIC IN LINE 240
270 X=USR(EB):IF X=0 THEN530: REM ** ENABLE BLINKMODE
280 C$=RD$
290 GOSUB450
300 X=USR(MB+(16*2)+0):REM ** BLACK BLINKS TO RED
310 X=USR(MB+(16*3)+1):REM * WHITE BLINKS TO CYAN
320 X=USR(MB+(16*7)+4):REM ** MAKE PURPLE BLINK TO YELLOW
330 X=USR(SD+14): REM ** SET BLINK SPEED
340 PRINT:PRINT"[156]   *** WARNING *** "
350 PRINT:PRINT"HIT A KEY TO CHANGE"
360 GOSUB530
370 X=USR(SB+0):REM **  STOP BLACK FROM BLINKING TO RED
380 X=USR(VB+0):IF X<>0 THEN380:REM ** WAIT UNTIL BLACK RESET
390 X=USR(MB+(16*5)+0):REM ** NOW BLINK BLACK TO GREEN
400 C$=GR$:GOSUB450
410 GOSUB530
420 X=USR(SB+0):REM **  STOP BLACK FROM BLINKING TO GREEN
430 X=USR(VB+0):IF X<>0 THEN430:REM ** WAIT UNTIL BLACK RESET
440 GOTO280
450 PRINT"ATTENTION - ATTENTION":PRINT
460 PRINT"[144]   CONDITION  CODE "
470 PRINT"   [213][192][192][192][192][192][192][192][192][192][192][192][192][192][201] "
480 PRINT"   [221]             [221] "
490 PRINT"   "C$
500 PRINT"   [221]             [221] "
510 PRINT"   [202][192][192][192][192][192][192][192][192][192][192][192][192][192][203] "
520 RETURN
530 TX=10:TY=20
540 GET A$:TY=TY-1:IF TY<0 THEN TY=20:X=USR(SD+TX):TX=TX-1:IF TX=0 THEN TX=1
550 CT$=" ":IF TX/2=INT(TX/2)THEN CT$="[209]"
560 PRINT""
570 X=USR(VB+0):REM ** NOW FIND THE COLOR BLACK IS BLINKING TO
580 POKECO,X:REM ** CHANGE CURRENT CHARACTER COLOR TO BLINKING COLOR
590 PRINTTAB(TY);CT$;
600 IF A$="" THEN540
610 X=USR(SD+14):RETURN